breed [particles particle]

particles-own [
  cur-pos
  velocity
  best-pos
  phi-1
  phi-2
]

patches-own [
  background-value
]

globals [
  best-particle
  global-best-pos
]

to setup
  ca
  create-particles number
  ask particles [ initialize-particle ]
  set best-particle one-of particles
  set global-best-pos cur-pos-of best-particle
end

to initialize-particle
  fd random world-width / 2
  set shape "circle"
  set color red
  set cur-pos list xcor ycor
  set best-pos cur-pos
  set velocity list
   (random-float max-velocity - max-velocity / 2)
   (random-float max-velocity - max-velocity / 2)
  set phi-1 random-float 2
  set phi-2 random-float 2
end

to go
  ask particles [
    update-velocity 
    update-position
    update-best ]
  update-global-best
  plot evaluate global-best-pos
end

to update-velocity
  if variable-phis? [
    set phi-1 random-float 2
    set phi-2 random-float 2
  ]
  set velocity vec-sum (vec-scale inertia velocity)
    (vec-sum (vec-scale phi-1 (vec-dif best-pos cur-pos))
      (vec-scale phi-2 (vec-dif global-best-pos cur-pos)))
  if magsq velocity > max-velocity ^ 2
   [ set velocity vec-scale (max-velocity / sqrt (magsq velocity)) velocity ]
end

to update-position
  let new-pos vec-sum cur-pos velocity
  if coll-avoidance? [
    if any? particles-at (item 0 velocity) (item 1 velocity) [
      set velocity vec-scale -1 velocity
      set new-pos vec-sum cur-pos velocity
    ]
  ]
  set cur-pos new-pos
  setxy (item 0 cur-pos) (item 1 cur-pos)
end

to update-best
  if evaluate cur-pos > evaluate best-pos
  [ set best-pos cur-pos ]
end

to update-global-best
  let new-best-particle max-one-of particles [ evaluate cur-pos ]
  if evaluate cur-pos-of new-best-particle > evaluate global-best-pos
    [ set color-of best-particle red
      set best-particle new-best-particle
      set color-of best-particle yellow
      set global-best-pos cur-pos-of best-particle ]
end

to-report evaluate [pos]
  ifelse test-function = "2007" [ report test-2007 pos ] [
  ifelse test-function = "two peaks" [ report test-two-peaks pos ] [
  ]]
end

to-report test-2007 [pos]
  let max-dist sqrt (world-width ^ 2 + world-height ^ 2) / 2
  let pos-dist sqrt (magsq vec-dif pos [20 07])
  report 100 * (1 - pos-dist / max-dist)
   + opt-background-value pos
end

to-report test-two-peaks [pos]
  let max-dist sqrt (world-width ^ 2 + world-height ^ 2) / 2
  let pos-dist sqrt (magsq vec-dif pos [20 07])
  report 9 * max list 0 (10 - (magsq vec-dif pos [20 07]))
   + 10 * (1 - pos-dist / max-dist)
   + 70 * (1 - sqrt (magsq vec-dif pos [-20 -07]) / max-dist)
   + opt-background-value pos
end

to initialize-background
  ask patches [ set background-value random-float background-level ]
end

to-report opt-background-value [pos]
  ifelse include-background?
  [ report background-value-of patch
     limit (round (item 0 pos)) min-pxcor max-pxcor
     limit (round (item 1 pos)) min-pycor max-pycor ]
  [ report 0 ]
end

to-report limit [val LB UB]
  report min list UB (max list LB val)
end

to-report vec-sum [u v]
  report (map [?1 + ?2] u v)
end

to-report vec-dif [u v]
  report (map [?1 - ?2] u v)
end

to-report vec-scale [s v]
  report map [s * ?] v
end

to-report magsq [v]
  report (item 0 v) ^ 2 + (item 1 v) ^ 2
end

to show-obj-function
  ask patches [ set pcolor scale-color green (evaluate (list pxcor pycor)) 0 100 ]
end

to hide-obj-function
  ask patches [ set pcolor black ]
end
@#$#@#$#@
GRAPHICS-WINDOW
303
10
801
529
30
30
8.0
1
10
1
1
1
0
1
1
1
-30
30
-30
30

CC-WINDOW
5
566
810
661
Command Center
0

SLIDER
23
13
245
46
number
number
0
500
100
1
1
particles

SLIDER
22
98
194
131
inertia
inertia
0
1
0.9
0.01
1
NIL

BUTTON
23
51
89
84
NIL
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
46
305
160
338
show obj function
show-obj-function
NIL
1
T
OBSERVER
T
NIL

BUTTON
165
305
279
338
hide obj function
hide-obj-function
NIL
1
T
OBSERVER
T
NIL

MONITOR
151
349
203
398
merit
evaluate global-best-pos
0
1

PLOT
28
402
296
552
Global Best
time
merit
0.0
10.0
0.0
100.0
true
false

MONITOR
206
349
295
398
best particle
best-particle
0
1

BUTTON
93
51
174
84
go once
go
NIL
1
T
OBSERVER
T
NIL

BUTTON
177
51
246
84
go
go
T
1
T
OBSERVER
T
NIL

CHOOSER
20
250
127
295
test-function
test-function
"2007" "two peaks"
0

SLIDER
22
136
194
169
max-velocity
max-velocity
0
20
1.0
0.1
1
NIL

MONITOR
28
348
85
397
best X
item 0 global-best-pos
3
1

MONITOR
91
349
148
398
bext Y
item 1 global-best-pos
3
1

SWITCH
131
251
296
284
include-background?
include-background?
1
1
-1000

SLIDER
131
213
295
246
background-level
background-level
0
100
25
1
1
NIL

BUTTON
22
212
127
245
init background
initialize-background
NIL
1
T
OBSERVER
T
NIL

SWITCH
22
173
154
206
variable-phis?
variable-phis?
1
1
-1000

SWITCH
161
174
294
207
coll-avoidance?
coll-avoidance?
1
1
-1000

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates the Particle Swarm Optimization technique developed by Kennedy and Eberhart (see CREDITS AND REFERENCES below).  Particle Swarm Optimization (PSO) uses a population of particles to cooperatively search for the best solution to a problem, represented by positions in a space, where each location has a "quality" ("goodness") determined by some Objective Function or Figure of Merit.  It was originally intended as a simple model of socially acquired knowledge, in that each particle's search is guided both by its own private knowledge of the best solution it has found so far and by social knowledge, namely the best solution found by all the particles.  PSO is commonly used to search high-dimensional spaces, but in this model we search a two-dimensional space, which is easier to visualize.


HOW IT WORKS
------------
Each particle k has a current position Xk, a current velocity Vk, and a remembered best location Pk (all two-dimensional vectors).  In addition, all particles know g, the index of the particle that has found the best position so far, so that Pg is the best location that anyone has found.  The velocity update rule is:

	Vk' = w Vk + Phi1 (Pk - Xk) + Phi2 (Pg - Xk)

where w is an inertia parameter and Phi1 and Phi2 are random numbers uniformly distributed in [0, 2].  They determine the extent to which the particle steers towards its own best solution (Pk) or the population's best solution (Pg).  The particle's position is updated by:

	Xk' = Xk + Vk'

In addition, if the quality of Xk' is greater that that of Pk, then the individual best is updated, Pk := Xk'.  Also, if the quality of Pk is better than the population's best, Pg, then the latter is updated, Pg := Pk.


HOW TO USE IT
-------------
NUMBER controls the number of particles.

SETUP initializes the particles with random positions and velocities.

GO ONCE and GO cause the particles to update their positions and velocities according to the particle swarm equations.

INERTIA sets the particles' inertia (see HOW IT WORKS).

MAX VELOCITY sets the maximum particle velocity; particles that would have a greater velocity (according to the rules) have it scaled back to this maximum, but without changing the direction.

VARIABLE PHIS? determines whether the random Phi1 and Phi2 values for each particle are determined once, when the particles are created, or whether they are recalculated every time a particle moves.  The former gives the particles fixed "personality types" wheras the latter allows them to change dispositions at any time.

COLL. AVOIDANCE? determines whether the particles avoid colliding with each other, and maintain greater diversity and ability to explore.  When COLL. AVOIDANCE? is turned on, a particle looks ahead to see if its next step would take it to a location where there is already a particle.  If so, it negates its velocity vector, so in effect it bounces backward and continues in this new direction.

INIT BACKGROUND initalizes a noisy fitness (objective function) background, with a maximum level determined by BACKGROUND LEVEL.  This is included in the fitness evaluation computation if INCLUDE BACKGROUND? is turned on.  Note that SETUP clears the background, so INIT BACKGROUND should be done after SETUP.

TEST FUNCTION selects the objective function to be used.  "2007" has a peak at coordinates (20, 07) (upper right).  "Two peaks" has a global optimum at (20, 07) and a much braoder suboptimum at (-20, -07).

SHOW OBJ FUNCTION and HIDE OBJ FUNCTION determine whether the objective function is displayed in the background.  Click on SHOW after the objctive function is selected and the fitness background is initialized (if you use the background).

BEST X and BEST Y show the best location found so far; MERIT is the quality of the current best solution, and BEST PARTICLE is the particle that found it.

GLOBAL BEST plots the quality of the best solution.


THINGS TO NOTICE
----------------
With the "two peaks" test the particles may get trapped by the suboptimum; this is an example of "premature convergence."


THINGS TO TRY
-------------
Try turning on collision avoidance and setting the max velocity high (10-15).  The particles bounce around alot more, but do they find the global optimum better?


EXTENDING THE MODEL
-------------------
Add new test models.  Read the PSO literature and try some of the new ideas to improve its performance.  Recode the particles to use Netlogo's movement abilities rather than the vector calculations in this simulation.


RELATED MODELS
--------------
PSO is related to models of flocking behavior in birds.  In what ways is it different?


CREDITS AND REFERENCES
----------------------
Particle swarm optimization was invented by Kennedy & Eberhart:

Kennedy, J., & Eberhart, R. ÒParticle Swarm Optimization,Ó Proc. IEEE IntÕl. Conf. Neural Networks (Perth, Australia), 1995.  See < http://www.engr.iupui.edu/~shi/pso.html >.

Krink, T., Vesterstr¿m, J.S., and Riget, J. ÒParticle Swarm Optimization with Spatial Particle Extension,Ó World Conference on Computational Intelligence, 2002.  This paper describes and tests collision avoidance.  See < http://www.evalife.dk >, < krink,jve,riget@daimi.au.dk >.

To refer to this model in academic publications, please use:  MacLennan, B.J. (2007).  NetLogo Particle Swarm Optimization model.  http://www.cs.utk.edu/~mclennan.  Dept. of Electrical Engineering & Computer Science, Univ. of Tennessee, Knoxville.

In other publications, please use:  Copyright 2007 Bruce MacLennan.  All rights reserved.  See http://www.cs.utk.edu/~mclennan/420/NetLogo/PSO.html for terms of use.

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.1.4
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@