SUBROUTINE CLARGV( N, X, INCX, Y, INCY, C, INCC )
*
*  -- LAPACK auxiliary routine (version 3.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     June 30, 1999
*     9-15-00:  New version continuous in r(i) (eca)
*     12-4-00:  Give D the sign of Re(f) for |g| > |f| (eca)
*
*     .. Scalar Arguments ..
      INTEGER            INCC, INCX, INCY, N
*     ..
*     .. Array Arguments ..
      REAL               C( * )
      COMPLEX            X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  CLARGV generates a vector of complex plane rotations with real
*  cosines, determined by elements of the complex vectors x and y.
*  For i = 1,2,...,n
*
*     (        c(i)   s(i) ) ( x(i) ) = ( r(i) )
*     ( -conjg(s(i))  c(i) ) ( y(i) ) = (   0  )
*
*  where c(i)**2 + ABS(s(i))**2 = 1.
*
*  Arguments
*  =========
*
*  N       (input) INTEGER
*          The number of plane rotations to be generated.
*
*  X       (input/output) COMPLEX array, dimension (1+(N-1)*INCX)
*          On entry, the vector x.
*          On exit, x(i) is overwritten by r(i), for i = 1,...,n.
*
*  INCX    (input) INTEGER
*          The increment between elements of X. INCX > 0.
*
*  Y       (input/output) COMPLEX array, dimension (1+(N-1)*INCY)
*          On entry, the vector y.
*          On exit, the sines of the plane rotations.
*
*  INCY    (input) INTEGER
*          The increment between elements of Y. INCY > 0.
*
*  C       (output) REAL array, dimension (1+(N-1)*INCC)
*          The cosines of the plane rotations.
*
*  INCC    (input) INTEGER
*          The increment between elements of C. INCC > 0.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
      COMPLEX            CZERO
      PARAMETER          ( CZERO = ( 0.0E+0, 0.0E+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IC, IX, IY
      REAL               CS, D, F1, F2, G1, G2
      COMPLEX            F, FS, G, GS, R, SN, Z
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ABS, AIMAG, CONJG, MAX, REAL, SQRT
*     ..
*     .. Statement Functions ..
      REAL               ABS1, ABSSQ
*     ..
*     .. Statement Function definitions ..
      ABS1( Z ) = MAX( ABS( REAL( Z ) ), ABS( AIMAG( Z ) ) )
      ABSSQ( Z ) = REAL( Z )**2 + AIMAG( Z )**2
*     ..
*     .. Executable Statements ..
*
      IX = 1
      IY = 1
      IC = 1
      DO 60 I = 1, N
         F = X( IX )
         G = Y( IY )
*
*        Use identical algorithm as in CLARTG
*
         IF( G.EQ.CZERO ) THEN
            C( IC ) = SIGN( ONE, REAL(F) )
            X( IX ) = F*C( IC )
         ELSE IF( F.EQ.CZERO ) THEN
            C( IC ) = ZERO
            Y( IY ) = CONJG(G) / ABS( G )
            X( IX ) = ABS( G )
         ELSE
            F1 = ABS1(F)
            G1 = ABS1(G)
            IF( F1.GE.G1 ) THEN
               FS = F / F1
               F2 = ABSSQ( FS )
               GS = G / F1
               G2 = ABSSQ( GS )
               D = SIGN( SQRT( ONE + G2 / F2 ), REAL(F) )
               CS = ONE / D
               C( IC ) = CS
               Y( IY ) = CONJG( GS )*FS*( CS / F2 )
               X( IX ) = F*D
            ELSE
               FS = F / G1
               F2 = ABSSQ( FS )
               GS = G / G1
               G2 = ABSSQ( GS )
               D = SIGN( G1*SQRT( F2 + G2 ), REAL(F) )
               F1 = ABS( F )
               FS = F / F1
               C( IC ) = F1 / D
               Y( IY ) = ( CONJG( G ) / D )*FS
               X( IX ) = FS*D
            END IF
         END IF
         IC = IC + INCC
         IX = IX + INCX
         IY = IY + INCY
   60 CONTINUE
      RETURN
*
*     End of CLARGV
*
      END